camera { 
      sky <0,0,1>           // Vektor, der festlegt, wo oben ist.
      right <-4/3,0,0>     // Bildverhältnis 4:3, plus Spiegelung für rechtsdrehendes System
      location <8,4,6>    // Position der Kamera
      look_at <1, 1, 1>    // Blickrichtung (erscheint im Bildmittelpunkt)
      angle 35             // Öffnungswinkel der Kamera
}

// Lichtquellen
light_source { 
 <6,-2,8>              // Position des Lichts
 color rgb <1,1,1>     // Farbe des Lichts, als rot-grün-blau Vektor (Komponenten 0 bis 1)
}
light_source { 
 <3,10,3>              // Position des Lichts
 color rgb <1,1,1>     // Farbe des Lichts, als rot-grün-blau Vektor (Komponenten 0 bis 1)
}


//
//  KUGEL
//


#declare hoehe=2;
// Start und Ende auf selber Höhe!
#declare start=<0,-1,0>;
#declare ende=<0,1,0>;

// Erst mal speichern, damit Wiederverwendung einfacher
#declare kugel = sphere {
	start+clock*(ende-start) + 4*hoehe*clock*(1-clock)*z, 0.2  // Kugel mit linearer Bewegung von start zu ende, plus quadratische z-Koordinate
	pigment {color rgb x+y}
	translate 0.2*z  // Damit die Kugel den Boden berührt und nicht darin versinkt.
}

//
// Zylinder
//

#declare startzyl=<2,1,0>;
#declare zylinder = cylinder { 0, -2*z, 0.2
	pigment {checker color rgb x color rgb y scale 0.125}
	// linear
	translate startzyl + clock*(ende-startzyl)
	// z-Richtung
	translate sin(2*pi*clock)*0.2*z
}

plane { z, -0.2
	pigment { checker  color rgb 0.5*x color rgb 0.5*z  scale 0.3333 }
}

// Kugel und Zylinder anzeigen
object  { kugel }
object {zylinder }