// Kamera
camera { 
  sky <0,0,1>           // Vektor, der festlegt, wo oben ist.
  right <-4/3,0,0>     // Bildverhältnis 4:3, plus Spiegelung für rechtsdrehendes System
  location <10,7,11>    // Position der Kamera
  look_at <0, 0, 0>    // Blickrichtung (erscheint im Bildmittelpunkt)
  angle 40             // Öffnungswinkel der Kamera
}
 
// Lichtquellen
light_source { 
  <6,-2,8>              // Position des Lichts
  color rgb <1,1,1>     // Farbe des Lichts, als rot-grün-blau Vektor (Komponenten 0 bis 1)
}
light_source { 
  <3,10,3>              // Position des Lichts
  color rgb <1,1,1>     // Farbe des Lichts, als rot-grün-blau Vektor (Komponenten 0 bis 1)
}
 
plane {z,-3
  pigment  {granite scale 10}
  normal { bozo }
  finish { reflection 0.9}
}
 
#declare umdrehung=-8; // Start der Umdrehungen
#declare ende=2;       // Ende der Umdrehungen
#declare sf=1.6;     // Streckfaktor pro Umdrehung
#declare schritte=30;  // 50 Schritte pro Umdrehung  
#declare num=0 ;  
 
#while (umdrehung<ende)  
  #declare r = pow(sf,umdrehung);  // sf hoch umdrehung
torus {0.3*r, 0.09*r
  #if (mod(num,3) = 0)
      pigment {color rgb <2,3,1>}
    #else 
      pigment {color rgb <0.5,0.03,1>}
    #end
 
 rotate 90*z      
  translate y*r 
  rotate umdrehung*360*z  
  translate 0.5*r
  }
 #declare num =num+1; 

 
  #declare umdrehung = umdrehung + 1/schritte;
#end //while